Hi Rich (and all) !
Following your advice, I contacted Vitalyi and will send him my card, and he will see if it could be repaired.
In the mean time I want to show to you all what I did with this hardware before it went down :
1/ My SETUPs
I tried different ways to partition the 8Gb CF chip, but with too big blocks and/or too large fats (ram resident !). Which tended to block the QL with (or without) "not enough memory" messages.
Finally, I did some tests with three smaller CF chips (one of 1Gb and two of 512Mb), and found my final choice of partition structure :
all to be of 40Mb with 2Kb blocksize which gave :
24 partitions on the 1Gb CF chip
12 partitions on the 512Mb CF chips
On the 8Gb CF chip, I decided to make 24 partitions like on the 1Gb chip and 7 900Mb - 32Kb blocks partitions, that I will try to use through direct/alien access (with the intent of swapping quickly stored images from and to the 32Kb screen ram).
Here are the automatic SETUP procedures that I wrote (for the 8Gb CF but easy to adapt to others CF sizes) :
Code: Select all
TK2_EXT : MODE 4
REM to make a partition Npart with given Size,SPB,Name$
10 DEFine PROCedure MAKE_PART( Npart,Size,SPB,Name$ )
20 WIN_FORMAT 11,SPB
30 WIN_DISK "CREATE",1,Npart,Size
40 WIN_DRIVE 1,1,Npart
50 FORMAT "WIN1_" & Name$
60 WIN_FORMAT 0 : DIR WIN1_
70 WIN_CTRL 1,6 : WIN_DRIVE -1
80 END DEFine MAKE_PART
REM First 1Gb is split into 24 40Mb/2Kb partitions
REM to make the first partition called GIRL
90 DEFine PROCedure MAKE_GIRL
100 MAKE_PART 1,40,4,"GIRL"
110 END DEFine MAKE_GIRL
REM to make 5 partitions called BOY1 to BOY5
120 DEFine PROCedure MAKE_BOYS
130 FOR I = 1 TO 5
140 MAKE_PART 1+I,40,4,"BOY" & CHR$(48+I)
150 END FOR I
160 END DEFine MAKE_BOYS
REM to make 9 partitions called CAT1 to CAT9
170 DEFine PROCedure MAKE_CATS
180 FOR I = 1 TO 9
190 MAKE_PART 6+I,40,4,"CAT" & CHR$(48+I)
200 END FOR I
210 END DEFine MAKE_CATS
REM to make 9 partitions called DOG1 to DOG9
220 DEFine PROCedure MAKE_DOGS
230 FOR I = 1 TO 9
240 MAKE_PART 15+I,40,4,"DOG" & CHR$(48+I)
250 END FOR I
260 END DEFine MAKE_DOGS
REM Next 7Gb are split into 7 900Mb/32Kb partitions
REM called COW1 to COW9 (because much bigger)
REM The last tracks may define a 9Mb/2Kb "MILK" ;-)
270 DEFine PROCedure MAKE_COWS
280 FOR I = 1 TO 7
290 MAKE_PART 24+I,900,8,"COW" & CHR$(48+I)
300 END FOR I
310 MAKE_PART 32,9,4,"MILK"
320 END DEFine MAKE_COWS
REM to declare any (0 to 31) partition as WIN1_
330 DEFine PROCedure GAL(N)
340 WIN_DRIVE -1 : WIN_DRIVE 1,1,N+1
350 END DEFine GAL
REM to declare any (1 to 31) partition as WIN2_
360 DEFine PROCedure PET(N)
370 WIN_DRIVE 2 : WIN_DRIVE 2,1,N+1
380 END DEFine PET
REM to make all partitions and unzip into "MILK"
REM the content of Haoui's StarterKit floppy
390 DEFine PROCedure SETUP
400 WIN_DRIVE -1 : WIN_FORMAT 1 : REM to allow INIT etc.
410 WIN_DISK "SHOW"
420 WIN_DISK "INIT",1
430 WIN_DISK "DETAILS",1
490 WIN_DISK "SUMMARY",1
500 GAL 0 : PET 31 : REM change 31 if NO partition "MILK" !
510 COPY flp1_UNZIP_EXE to WIN2_ETC_UNZIP_EXE
520 COPY flp1_starter1_zip to WIN2_QubATA_STARTER1_ZIP
530 EW WIN2_ETC_UNZIP_EXE;"-d WIN2_ WIN2_QubATA_STARTER1_ZIP"
540 END DEFine SETUP
FIRST a short MAKE_PART procedure to factorize all the steps creating a partition : with a given number, a given size, a given blocksize code and a given name.
THEN several instanciation procedures :
MAKE_GIRL to create the #1 (boot) partition
MAKE_BOYS to create 5 BOYn partitions
MAKE_CATS to create 9 CATn partitions
MAKE_DOGS to create 9 DOGn partitions
All these partitions are 40Mb with 2Kb blocks (thus 80Kb fat)
FOR THE 8Gb CF I added :
MAKE_COWS to create 7 much bigger COWn partitions of 900Mb with 32Kb blocks, and a little MILK partition to use the remaining tracks.
FINALLY, there is a SETUP procedure that initialise the CF chip, calls all the instanciation procedures and unzips the Haoui Starter flp_ into the MILK partition : because I wanted to be able to decide where I want to put what.
BY THE WAY, I added also two little procedures :
PET n to change the partition linked to WIN2_
GAL n to change eventually the partition linked to WIN1_ (and unlink any partition linked to WIN2_ ; so after calling GAL, you have to call PET).
To be noted : I prefered to number GIRL as partition 0 !
May the FORTH (and SuperBasic) be with you !